Codefixer - 3 Column Table Layout using Mod Operator

The code below retrieves a recordset from our "tblFriends" table in the database 'Friends.mdb'. The table has 3 columns, firstly an 'ID' field that is an autonumber, secondly a field called 'FirstName' which is a textfield and lastly another textfield called 'SurName'. The code displays the results in a 3 column table layout.

If you wish to change the number of columns displayed then simply change the line If iColumnSpan Mod 3 =0 Then, with 3 being the number of columns you want.

The VBScript Mod operator divides two numbers and returns the remainder. So in our code if iColumnSpan is divisible by 3 leaving a remainder of 0 then start a new table row.

<%@ Language="VBScript" %>
<% Option Explicit %>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
<head>
<title>3 column layout</title>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
</head>
<body>
<%
'declare your variables
Dim Connection, Recordset
Dim sSQL, sConnString, iColumnSpan

'declare SQL statement that will query the database
sSQL="SELECT FirstName, SurName FROM tblFriends"

'define the connection string, specify database
'driver and the location of database
sConnString="PROVIDER=Microsoft.Jet.OLEDB.4.0;" & _
"Data Source=" & Server.MapPath("Friends.mdb")

'create an ADO connection and recordset
Set connection = Server.CreateObject("ADODB.Connection")
Set recordset = Server.CreateObject("ADODB.Recordset")

'Open the connection to the database
connection.Open sConnString

'Open the recordset object, execute the SQL statement
recordset.Open sSQL, connection

'first of all determine whether there are any records
If Recordset.EOF Then
Response.Write("No records returned.")
Else

Response.write "<table width=""100%"" border=""1"">"
'iColumnSpan is used as a column counter
iColumnSpan=0
response.write "<tr>"
'If there are records then loop through the fields
Do While Not recordset.EOF

If iColumnSpan Mod 3 = 0 Then
'Although 0 divided by 3 gives a reminder of 0 don't start a new row
If iColumnSpan<> 0 Then
response.write "</tr><tr>"
End If
End If

response.write "<td>"
response.write recordset("FirstName") & " " & recordset("SurName")
response.write "</td>"

iColumnSpan=iColumnSpan + 1

'move on to the next record
Recordset.MoveNext
Loop

response.write "</tr>"
Response.write "</table>"

End If

'close the connection and recordset objects and free up resources
Recordset.Close
Connection.Close
Set Recordset = Nothing
Set Connection = Nothing
%>
</body>
</html>

If you have any code snippets to share with full credit given then send an email to Codesnippets - You'll receive full credit and a link back to your site.

Display your recordset in a 3 column table layout using the Mod Operator